SOM.ALS in Excel: zo gebruik je het
Engels: SUMIF
SOM.ALS maakt een totaal van alleen de rijen die jij wilt: eerst waar je zoekt, dan wat je zoekt, dan wat je optelt.
Probeer gratis de eerste oefeningenIn de les Optellen met SOM.ALS
Wat doet SOM.ALS?
SOM.ALS telt alleen de getallen op uit de rijen die aan een voorwaarde voldoen. Je geeft drie dingen op: waar Excel de voorwaarde controleert, wat de voorwaarde is, en welke kolom het moet optellen.
Zo maak je zonder filter of draaitabel een totaal per groep: de omzet van één regio, de uitgaven van één maand, de uren van één medewerker. Verandert er iets in de lijst, dan rekent de formule meteen mee.
Wanneer gebruik je SOM.ALS?
- De omzet van één regio: =SOM.ALS(A2:A100;"Gent";C2:C100).
- Alle bedragen boven 500: =SOM.ALS(C2:C100;">500").
- De uren van één medewerker in een urenlijst: =SOM.ALS(A2:A60;"Sofie";D2:D60).
- Een overzicht per regio, met de regio uit een cel: =SOM.ALS($A$2:$A$100;F2;$C$2:$C$100).
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Ingevuld: =SOM.ALS(A2:A6;"Gent";C2:C6)
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
SOM.ALS | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | SOM.ALS |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
bereik | De kolom waarin je de voorwaarde controleert. | A2:A6 |
voorwaarde | Wat je zoekt, bijvoorbeeld "Gent". | "Gent" |
[optelbereik] | Niet verplicht. Optioneel: de kolom met de bedragen. | C2:C6 |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
" " | Tekst typ je tussen aanhalingstekens, zoals "Gent". Een getal of een cel, zoals 500 of A2, typ je zonder. | |
[ ] | Wat tussen rechte haken staat, mag je weglaten. De haken zelf typ je nooit. |
SOM.ALS stap voor stap
In E1 staat =SOM.ALS(A2:A6;"Gent";C2:C6). 1200 + 410: alleen de rijen van Gent. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Typ in E1 de functie met een haakje.
=SOM.ALS( - Selecteer waar Excel moet zoeken: de regio's in A2 tot en met A6. Typ een puntkomma.
=SOM.ALS(A2:A6; - Typ wat Excel moet zoeken, tussen aanhalingstekens: "Gent". Typ weer een puntkomma.
=SOM.ALS(A2:A6;"Gent"; - Selecteer wat Excel moet optellen: de omzetten in C2 tot en met C6.
=SOM.ALS(A2:A6;"Gent";C2:C6 - Sluit het haakje en druk op Enter: 1200 + 410 = 1610.
=SOM.ALS(A2:A6;"Gent";C2:C6)
Meer voorbeelden
Optellen boven een grens
In E1 staat =SOM.ALS(C2:C6;">500"). Zonder derde deel telt Excel de kolom zelf op: alleen de omzetten boven 500, dus 1200 + 980.
Met de regio uit een cel
In F2 staat =SOM.ALS(A2:A6;E2;C2:C6). De regio komt uit E2. Typ er Sint-Niklaas in, en je krijgt 415.
Op een deel van een tekst
In D1 staat =SOM.ALS(A2:A5;"Laptop *";B2:B5). "Laptop *", met een spatie voor het sterretje, telt de twee laptops op, maar niet de laptoptas.
Een overzicht per regio
Zet de regio's in een kolom en verwijs daarnaar in plaats van de naam te typen. Zet de bereiken vast met $, dan kun je de formule doorvoeren.
Het hoogste of laagste met een voorwaarde
MAX.ALS.VOORWAARDEN en MIN.ALS.VOORWAARDEN zijn opgebouwd zoals SOMMEN.ALS: =MAX.ALS.VOORWAARDEN(C2:C6;A2:A6;"Gent") geeft de hoogste omzet uit Gent. Je hebt er Excel 2019 of nieuwer voor nodig.
Optellen boven of onder een bedrag
Een vergelijking schrijf je tussen aanhalingstekens. =SOM.ALS(C2:C6;">500") telt alleen de bedragen boven 500. Staat de grens in een cel, plak die er dan aan met &: =SOM.ALS(C2:C6;">"&E1).
Op een deel van een tekst zoeken
Een sterretje staat voor elke willekeurige tekst. =SOM.ALS(B2:B6;"*laptop*";C2:C6) telt elke rij op waarin het woord laptop voorkomt, ook als er nog iets voor of achter staat.
Meer dan één voorwaarde
Dan gebruik je SOMMEN.ALS. Daar staat wat je optelt vooraan: =SOMMEN.ALS(C2:C6;A2:A6;"Gent";B2:B6;"Laptop") telt de laptops in Gent.
Hier gaat het vaak mis
- Bij SOMMEN.ALS staat het optelbereik vooraan, bij SOM.ALS achteraan.
- Een getal dat als tekst staat, telt niet mee.
Oefen dit in de les Optellen met SOM.ALS, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Wat is het verschil met een draaitabel?
Een formule werkt meteen bij en past in je eigen layout. Een draaitabel maak je sneller, maar die moet je vernieuwen.
Lees ook
AANTAL en AANTALARGAANTAL.ALSAANTALLEN.ALSSOMMEN.ALSGEMIDDELDE.ALS