KIEZEN.KOLOMMEN in Excel: zo gebruik je het
Engels: CHOOSECOLS
KIEZEN.KOLOMMEN toont alleen de kolommen van een tabel die je kiest, in de volgorde die je wilt. KIEZEN.RIJEN, NEMEN en WEGLATEN doen dat met rijen. Werkt in Excel 365 en 2024.
Probeer gratis de eerste oefeningenIn de les Excel 365 voor gevorderden
Wat doet KIEZEN.KOLOMMEN?
KIEZEN.KOLOMMEN maakt een kopie van een tabel met alleen de kolommen die jij noemt. Je typt de formule in één cel, en het resultaat loopt over naar rechts en naar beneden. Verandert er iets in de tabel, dan verandert de kopie mee.
De kolommen komen in de volgorde van je nummers: met 3;1 staat de derde kolom vooraan. Een negatief getal telt van rechts, zodat -1 altijd de laatste kolom is. KIEZEN.KOLOMMEN werkt in Excel 365 en Excel 2024.
Voor rijen zijn er drie zusjes. KIEZEN.RIJEN werkt net zo, met rijnummers. NEMEN houdt de eerste rijen over, of met een minteken de laatste, en WEGLATEN laat ze juist weg. Samen met SORTEREN maak je zo een top drie die zichzelf bijwerkt.
Wanneer gebruik je KIEZEN.KOLOMMEN?
- Een overzicht met alleen de namen en de totalen uit een brede tabel: =KIEZEN.KOLOMMEN(A1:F50;1;6).
- Kolommen in een andere volgorde zetten: =KIEZEN.KOLOMMEN(A1:C20;3;1;2).
- De laatste kolom van een tabel, zonder te tellen: =KIEZEN.KOLOMMEN(A1:H20;-1).
- Twee kolommen kiezen en meteen sorteren: =SORTEREN(KIEZEN.KOLOMMEN(A2:D20;1;4);2;-1).
- De drie hoogste omzetten, die zichzelf bijwerken: =NEMEN(SORTEREN(A2:C50;3;-1);3).
- Een lijst zonder de titelrij: =WEGLATEN(A1:C50;1).
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Alleen de kolommen die je noemt, in die volgorde.
Ingevuld: =KIEZEN.KOLOMMEN(A1:C6;1;3)
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
KIEZEN.KOLOMMEN | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | KIEZEN.KOLOMMEN |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
matrix | De tabel of het bereik waaruit je kiest. | A1:C6 |
kolomnummer1 | De eerste kolom die je wilt zien. Tel vanaf 1, of met een minteken vanaf rechts: -1 is de laatste kolom. | 1 |
[kolomnummer2] | Niet verplicht: nog een kolom, en zo verder. De volgorde van de nummers is de volgorde in het resultaat. | 3 |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
[ ] | Wat tussen rechte haken staat, mag je weglaten. De haken zelf typ je nooit. | |
... | Je mag er nog meer opgeven, telkens met een puntkomma ertussen. |
KIEZEN.KOLOMMEN stap voor stap
In E1 staat =KIEZEN.KOLOMMEN(A1:C6;1;3). De kolommen Regio en Omzet, zonder de producten. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Klik in E1, met lege cellen rechts en eronder, en typ KIEZEN.KOLOMMEN met een haakje.
=KIEZEN.KOLOMMEN( - Selecteer de hele tabel, A1 tot en met C6, en typ een puntkomma.
=KIEZEN.KOLOMMEN(A1:C6; - Typ de nummers van de kolommen die je wilt zien: 1 voor Regio, een puntkomma, en 3 voor Omzet.
=KIEZEN.KOLOMMEN(A1:C6;1;3 - Sluit het haakje en druk op Enter: twee kolommen, zonder de producten.
=KIEZEN.KOLOMMEN(A1:C6;1;3)
Meer voorbeelden
De laatste kolom
In E1 staat =KIEZEN.KOLOMMEN(A1:C6;-1). -1 telt van rechts: de laatste kolom, Omzet.
In een andere volgorde
In E1 staat =KIEZEN.KOLOMMEN(A1:C6;3;1). Met 3;1 staat Omzet vooraan en Regio erachter.
Kiezen en sorteren
In E2 staat =SORTEREN(KIEZEN.KOLOMMEN(A2:C6;1;3);2;-1). De regio's met hun omzet, de hoogste eerst: Gent met 1.200 staat bovenaan.
De titelrij en de laatste rij
In E1 staat =KIEZEN.RIJEN(A1:C6;1;-1). Rij 1 met de kopjes, en met -1 de laatste rij: Sint-Niklaas, Muis, 75.
Een top twee met NEMEN
In E2 staat =NEMEN(SORTEREN(A2:C6;3;-1);2). SORTEREN zet de hoogste omzet bovenaan, en NEMEN houdt de eerste twee rijen over: Gent met 1.200 en Antwerpen met 980.
Hier gaat het vaak mis
- Een kolomnummer dat groter is dan je tabel, geeft #WAARDE!.
- Staat er iets in de cellen waar het resultaat moet komen, dan krijg je #OVERLOOP!.
Oefen dit in de les Excel 365 voor gevorderden, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Kan ik ook rijen kiezen?
Ja. KIEZEN.RIJEN werkt net zo, met rijnummers. NEMEN houdt de eerste of laatste rijen over en WEGLATEN laat ze weg: =NEMEN(SORTEREN(A2:C6;3;-1);3) geeft een top drie.