LET in Excel: zo gebruik je het
Met LET geef je een tussenresultaat een naam binnen je formule. Excel rekent het één keer uit, en een lange formule leest makkelijker. Werkt in Excel 2021 en 365.
Probeer gratis de eerste oefeningenIn de les Excel 365 voor gevorderden
Wat doet LET?
LET geeft een tussenresultaat een naam, binnen één formule. Je zet eerst de naam, dan wat hij betekent, en als laatste de berekening die de naam gebruikt. Excel rekent de waarde maar één keer uit, ook als je de naam vaker gebruikt.
Dat maakt lange formules korter en leesbaarder: in plaats van drie keer A2*B2 staat er drie keer totaal. Je kunt meer namen geven, telkens een naam en een waarde, en een naam mag een eerdere naam gebruiken. LET werkt in Excel 2021 en 365.
Wanneer gebruik je LET?
- Een berekening die drie keer terugkomt, zoals een totaal met korting: =LET(totaal;A2*B2;ALS(totaal>100;totaal*0,9;totaal)).
- Hoeveel procent een waarde boven of onder het gemiddelde ligt: =LET(gem;GEMIDDELDE(B2:B20);(B2-gem)/gem).
- Een opgezochte prijs controleren zonder twee keer te zoeken: =LET(p;X.ZOEKEN(E1;A2:A9;B2:B9;0);ALS(p=0;"Onbekend";p)).
- Een lange formule leesbaar maken met namen als prijs en aantal: =LET(prijs;A2;aantal;B2;prijs*aantal).
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Ingevuld: =LET(totaal;A2*B2;ALS(totaal>100;totaal*0,9;totaal))
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
LET | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | LET |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
naam | Een naam die je zelf kiest, zoals totaal of x. Hij mag niet op een celadres lijken. | totaal |
waarde | Wat de naam betekent: een getal, een cel, een bereik of een berekening. | A2*B2 |
berekening | De formule die de naam gebruikt. Dit argument staat altijd als laatste. | ALS(totaal>100;totaal*0,9;totaal) |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
LET stap voor stap
In C2 staat =LET(totaal;A2*B2;ALS(totaal>100;totaal*0,9;totaal)). 12,50 × 10 is 125, meer dan 100: met 10% korting betaal je 112,50. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Klik in C2 en typ LET met een haakje.
=LET( - Typ de naam, totaal, en een puntkomma.
=LET(totaal; - Geef wat de naam betekent, A2*B2, en typ een puntkomma.
=LET(totaal;A2*B2; - Typ de berekening met de naam: 10% korting als het totaal boven 100 ligt.
=LET(totaal;A2*B2;ALS(totaal>100;totaal*0,9;totaal) - Sluit het haakje en druk op Enter: 112,50.
=LET(totaal;A2*B2;ALS(totaal>100;totaal*0,9;totaal))
Meer voorbeelden
Twee namen
In C2 staat =LET(prijs;A2;aantal;B2;prijs*aantal). Twee namen, elk met hun waarde, en de berekening als laatste.
Het verschil met het gemiddelde
In D2 staat =LET(gem;GEMIDDELDE(B2:B4);(B2-gem)/gem). Het gemiddelde is 14. Lotte haalt 16: ongeveer 14% boven het gemiddelde.
Een naam die een eerdere naam gebruikt
In C2 staat =LET(totaal;A2*B2;btw;totaal*21%;totaal+btw). btw rekent met totaal: 125 plus 26,25 btw is 151,25.
Hier gaat het vaak mis
- Een naam mag niet op een celadres lijken: x of totaal kan, A1 of BTW1 niet.
- De naam bestaat alleen binnen die ene formule. In een andere cel kent Excel hem niet: daar krijg je #NAAM?.
Oefen dit in de les Excel 365 voor gevorderden, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Wat is het verschil met een benoemd bereik?
Een benoemd bereik geldt in de hele werkmap en verwijst naar cellen. Een naam in LET geldt alleen in die ene formule en kan elke berekening bevatten.